Improving the DHT model in A2
After playing for some time with the uTracer, I found that the tracer wasn’t measuring accurately A2 curves. Ronald clearly advised me (as explained on his site) that uTracer wasn’t designed for this purpose although there was a great trick to use the screen driver to generate the A2 curves and also measure grid current. Measuring grid current is key in A2 mode so a better grid current model can be derived to better simulate the non-linear and low impedance behavior of the grid in positive bias.
My incarnation of the uTracer is not neat. I’m using my existing analogue curve tracer. As shown in the pictures below, my current tracer have a plethora of sockets and just adding right jumper cables for anode, cathode, screen and grid connectors will still give me the flexibility I had with my analogue tracer
The process of generating the A2 curves (and SPICE model) starts by plotting the normal curves. The uTracer is great for this. Then you have to overlay the A2 curves in Excel (or whatever tool you prefer) to combine both set of curves.
4P1L is not a power transmitting valve and wasn’t designed for positive grid current operation. Despite this, it can withstand some abuse:
4P1L has a fantastic set of curves (I said it already like a dozen times). it’s extremely linear and interestingly when filaments are connected in series and with G3 at the filament center point, the mu is slightly higher (above 9) than when in wired parallel (about 8).
The grid current curves are shown below:
To use 4P1L in A2 a nice cathode follower or mu-follower grid driver is needed to provide the 10-20mA of grid current as shown above. This way we could get 5W out of a SE stage.
Ronald explained me why an additional 1,000uF is needed across C13 to improve the accuracy of the A2 grid and anode current tracing:
“The problem is in the way the boost converter work. The boost converter pulses charge which is in the inductor into the capacitor. After every 4 pulses the voltage of the capacitor is checked, and if the voltage of the capacitor is higher than the set point, the pulsing stops. When the voltage is very low, the increments can be large compared to the voltage itself (from energy conservation CVnew^2 = CVold^2 + Li^2). By increasing the capacitance, the increments become smaller. 3,300 uF is perhaps an overkill, 1,000uF will be good enough. I think and makes the discharging faster. An idea could be to add an additional discharge transistor which only discharges the 3300 uF cap with a much higher current.” (Ronald Dekker)I had a 3,300uF/63V at hand so simply hacked the uTracer by adding a switch for A2 mode and the 3,300uF capacitor with a 56V zener to protect it across it. This addition is only used during A2 mode.
Now let’s look at how well we can approximate the grid current. I played with the model for some minutes and quickly got a nice result:
The A2 curves also fit very well as shown below:
The model generated:
**** 4P1L TRIODE version 4 ** Composite DHT with Advanced Grid Current **************
* Created on 09/29/2013 08:35 using paint_kit.jar Version 2.4 Beta. May 2013
* www.bartola.co.uk/valves
* Created by Ale Moglia valves@bartola.co.uk using uTracer
* Plate Curves image file: 4P1L TRIODE 4
* Plate Data source link: www.bartola.co.uk/valves
*----------------------------------------------------------------------------------
.SUBCKT DHT_4P1L 4_A2 1 2 3 4 ; P G K1 K2
+ PARAMS: CCG=6P CGP=8P CCP=4P RFIL=13.5
+ MU=9.5 KG1=855 KP=150 KVB=745.3 VCT=0.407 EX=1.4
+ VGOFF=-3.94 IGA=0.01 IGB=0.432 IGC=11.8 IGEX=1.92
* Vp_MAX=350 Ip_MAX=140 Vg_step=5 Vg_start=10 Vg_count=9
* Rp=4000 Vg_ac=55 P_max=9 Vg_qui=-48
* X_MIN=77 Y_MIN=89 X_SIZE=492 Y_SIZE=526 FSZ_X=1157 FSZ_Y=724 XYGrid=false
*----------------------------------------------------------------------------------
RFIL_LEFT 3 31 {RFIL/4}
RFIL_RIGHT 4 41 {RFIL/4}
RFIL_MIDDLE1 31 34 {RFIL/4}
RFIL_MIDDLE2 34 41 {RFIL/4}
E11 32 0 VALUE={V(1,31)/KP*LOG(1+EXP(KP*(1/MU+V(2,31)/SQRT(KVB+V(1,31)*V(1,31)))))}
E12 42 0 VALUE={V(1,41)/KP*LOG(1+EXP(KP*(1/MU+V(2,41)/SQRT(KVB+V(1,41)*V(1,41)))))}
RE11 34 0 1G
G11 1 31 VALUE={(PWR(V(32),EX)+PWRS(V(32),EX))/(2*KG1)}
G12 1 41 VALUE={(PWR(V(42),EX)+PWRS(V(42),EX))/(2*KG1)}
RCP1 1 34 1G
C1 2 34 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 34 {CCP} ; CATHODE-PLATE
RE2 2 0 1G
EGC1 81 0 VALUE={V(2,31)-VGOFF} ; POSITIVE GRID THRESHOLD
GG1 2 31 VALUE={0.5*(IGA+IGB/(IGC+V(1,31)))*(MU/KG1)*(PWR(V(81),IGEX)+PWRS(V(81),IGEX))}
EGC2 82 0 VALUE={V(2,41)-VGOFF} ; POSITIVE GRID THRESHOLD
GG2 2 41 VALUE={0.5*(IGA+IGB/(IGC+V(1,41)))*(MU/KG1)*(PWR(V(82),IGEX)+PWRS(V(82),IGEX))}
.ENDS
*$
I’m very happy now with the performance of the uTracer and I recommend you highly to get one after tracing valves for many years with various tracers. In my view:
- The digital tracer can give you a wider flexibility for data analysis. Transferring the curves from the analogue tracer is hard work.
- The analogue tracer responds much faster and this is a good thing in some scenarios.
- uTracer is great value for money. You can plot characteristic and transfer curves, match valves, measure transconductance and even A2 curves!
- Building a uTracer is not for beginners. The kit is of supreme quality and Ronald provides a fantastic support via email. Even sent me a new PIC at no extra cost when I accidentally damaged it during the building process. If you are experienced with electronics, then go ahead and enjoy the building experience.
I promised Ronald a cartoon which I need to get done at some point!
Hope you enjoy the 4P1L curves!
Ale
Thanks for publishing your great work on this valve, Ale. I’m playing with your models in PSpice trying to come up with a PP or PPP contraption capable of A2 operation, and have a question regarding parameter RFIL=13.5ohm of your latest model. Why not the more realistic 3.23ohm from your previous model?
Series versus paralleled filaments used in both models.