6GE5 Pentode Model

A quick trace of a NOS Tung-Sol 6GE5 measuring around 113%:6ge5 test

Derived the Spice models using Dekker’s ExtractModel tool. The uTracer has a limit of 200mA so it’s not possible to trace the extended set of curves for this valve. However, this is not a limitation to produce a good model.

Here is the triode matching:

6ge5 triode
6ge5 triode

I run a set of curves at various screen voltages from 100V up to 200V at 25V steps to generate the pentode model The saturation effect is visible on higher currents above 140mA as you can see below:

6ge5 Vs=100V
6ge5 Vs=100V
6ge5 screen current at Vs=100V
6ge5 screen current at Vs=100V
6GE5 Vs=200V
6GE5 Vs=200V

Below is the triode model, you can download the model from here: 6ge4 triode model. Capacitance values aren’t correct so if someone measures these in triode-mode would be great.

****************************************************
.SUBCKT 6ge5-triode 1 2 3; A G C;
* Extract V1.998
* Model created: 19-Sep-2015
*
* Traced with uTracer v3 and model developed by Ale Moglia 
* www.bartola.co.uk/valves
* NOTE: LOG(x) is base e LOG or natural logarithm.
* For some Spice versions, e.g. MicroCap, this has to be changed to LN(x).
X1 1 2 3 TriodeK MU= 5.75 EX=1.372 KG1= 285.6 KP= 19.5 KVB= 1708. RGI=2000
+ CCG=16.0P CGP=0.34P CCP=7.0P ;
.ENDS
 
****************************************************
.SUBCKT TriodeK 1 2 3; A G C
E1 7 0 VALUE=
+{V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS TriodeK

Below is the pentode model, you can download the model from here: 6ge4 pentode model.

****************************************************
.SUBCKT 6ge5-vs100V 1 2 3 4 ; A G2 G1 C;
* Extract V1.998
* Model created: 19-Sep-2015
*
* Traced with uTracer v3 and model developed by Ale Moglia 
* www.bartola.co.uk/valves
*
* NOTE: LOG(x) is base e LOG or natural logarithm.
* For some Spice versions, e.g. MicroCap, this has to be changed to LN(x).
X1 1 2 3 4 BTetrodeDE MU= 5.75 EX=1.372 kG1= 285.6 KP= 19.5 kVB = 1708.3 kG2=14819.8
+Sc=.48E+00 ap= .011 w= 89. nu= 2.37 lam= 212.2
+ Ookg1mOokG2=.343E-02 Aokg1=.37E-05 alkg1palskg2=.343E-02 be= .094 als= 36.43 RGI=2000
+ CCG1=16.0P CCG2 = 0.0p CPG1 = 0.32p CG1G2 = 0.0p CCP=7.0P ;
.ENDS
 
****************************************************
.SUBCKT BTetrodeDE 1 2 3 4; A G2 G1 C
RE1 7 0 1MEG ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1 7 0 VALUE=
+{V(2,4)/KP*LOG(1+EXP(KP*(1/MU+V(3,4)/SQRT(KVB+V(2,4)*V(2,4)))))}
E2 8 0 VALUE = {Ookg1mOokG2 + Aokg1*V(1,4) - alkg1palskg2*Exp(-be*V(1,4)*SQRT(be*V(1,4)))}
E3 9 0 VALUE = {Sc/kG2*V(1,4)*(1+tanh(-ap*(V(1,4)-V(2,4)/lam+w+nu*V(3,4))))}
G1 1 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))*(V(8)-V(9))}
G2 2 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG2 *(1+als*Exp(-be*V(1,4) * SQRT(be*V(1,4))))}
RCP 1 4 1G ; FOR CONVERGENCE A - C
C1 3 4 {CCG1} ; CATHODE-GRID 1 C - G1
C4 2 4 {CCG2} ; CATHODE-GRID 2 C - G2
C5 2 3 {CG1G2} ; GRID 1 -GRID 2 G1 - G2
C2 1 3 {CPG1} ; GRID 1-PLATE G1 - A
C3 1 4 {CCP} ; CATHODE-PLATE A - C
R1 3 5 {RGI} ; FOR GRID CURRENT G1 - 5
D3 5 4 DX ; FOR GRID CURRENT 5 - C
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS BTetrodeDE

Parenthood is leaving me with limited free time these days so haven’t had the chance to test these models in LtSpice yet.

 

 

 

3 Replies to “6GE5 Pentode Model”

Leave a Reply