**** UX120 TRIODE SMALL Composite DHT *****************************************
* Created on 02/08/2020 16:44 using paint_kit.jar 2.9 
* www.dmitrynizh.com/tubeparams_image.htm
* Plate Curves image file: UX120 triode small.png
* Data source link: 
* Curve traced and model developed by Ale Moglia
* (c) 2020 by Bartola Valves UK Ltd.
* email: valves@bartola.co.uk / www.bartola.co.uk/valves

*----------------------------------------------------------------------------------
.SUBCKT DHT_UX-120 1 2 3 4 ; P G K1 K2
+ PARAMS: CCG=2P  CGP=4.1P CCP=2.3P RFIL=24
+ MU=3.28 KG1=16080 KP=27 KVB=351 VCT=-1.5 EX=1.43 RGI=2000
* Vp_MAX=200 Ip_MAX=14 Vg_step=5 Vg_start=0 Vg_count=12
* Rp=4000 Vg_ac=55 P_max=0.9 Vg_qui=-48 Vp_qui=300
*----------------------------------------------------------------------------------
RFIL_LEFT    3  31 {RFIL/4}
RFIL_RIGHT   4  41 {RFIL/4}
RFIL_MIDDLE1 31 34 {RFIL/4}
RFIL_MIDDLE2 34 41 {RFIL/4}
E11 32 0  VALUE={V(1,31)/KP*LOG(1+EXP(KP*(1/MU+V(2,31)/SQRT(KVB+V(1,31)*V(1,31)))))} 
E12 42 0  VALUE={V(1,41)/KP*LOG(1+EXP(KP*(1/MU+V(2,41)/SQRT(KVB+V(1,41)*V(1,41)))))} 
RE11 32 0 1G 
RE12 42 0 1G 
G11 1 31 VALUE={(PWR(V(32),EX)+PWRS(V(32),EX))/(2*KG1)} 
G12 1 41 VALUE={(PWR(V(42),EX)+PWRS(V(42),EX))/(2*KG1)} 
RCP1 1 34 1G 
C1 2 34 {CCG} ; CATHODE-GRID 
C2 2 1 {CGP} ; GRID=PLATE 
C3 1 34 {CCP} ; CATHODE-PLATE 
D3 5 3 DX ; FOR GRID CURRENT 
D4 6 4 DX ; FOR GRID CURRENT 
RG1 2 5 {2*RGI} ; FOR GRID CURRENT 
RG2 2 6 {2*RGI} ; FOR GRID CURRENT 
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N) 
.ENDS 
*$