****************************************************
.SUBCKT RL12P35-pentode 1 2 3 4 ; A G2 G1 C;
*      Extract V3.000
* Model created: 28-May-2016
*
* Traced and model created by Ale Moglia  / valves@bartola.co.uk
* www.bartola.co.uk/valves
*
*
*
X1 1 2 3 4 BTetrodeDE  MU=  5.01 EX=1.331 kG1= 676.1 KP=  14.9 kVB = 1008.8 kG2= 3519.4
+Sc=.12E+00 ap=  .034 w=    16. nu=   .24 lam=    11.8
+ Ookg1mOokG2=.119E-02 Aokg1=.46E-06 alkg1palskg2=.119E-02 be=  .151 als=  3.10 RGI=2000
+ CCG1=16.5P  CCG2 = 0.0p CPG1 = 0.05p  CG1G2 = 5.7p CCP=10.4P  ;
.ENDS

****************************************************
.SUBCKT BTetrodeDE 1 2 3 4; A G2 G1 C
*
* NOTE: LOG(x) is base e LOG or natural logarithm.
* For some Spice versions, e.g. MicroCap, this has to be changed to LN(x).
*
RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1 7 0 VALUE=
+{V(2,4)/KP*LOG(1+EXP(KP*(1/MU+V(3,4)/SQRT(KVB+V(2,4)*V(2,4)))))}
E2   8 0 VALUE = {Ookg1mOokG2 + Aokg1*V(1,4) - alkg1palskg2*Exp(-be*V(1,4)*SQRT(be*V(1,4)))}
E3   9 0 VALUE = {Sc/kG2*V(1,4)*(1+tanh(-ap*(V(1,4)-V(2,4)/lam+w+nu*V(3,4))))}
G1   1 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))*(V(8)-V(9))}
G2   2 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG2 *(1+als*Exp(-be*V(1,4) * SQRT(be*V(1,4))))}
RCP  1 4  1G      ; FOR CONVERGENCE	A  - C
C1   3 4  {CCG1}   ; CATHODE-GRID 1	C  - G1
C4   2 4  {CCG2}   ; CATHODE-GRID 2	C  - G2
C5   2 3  {CG1G2}   ; GRID 1 -GRID 2	G1  - G2
C2   1 3  {CPG1}  ; GRID 1-PLATE	G1 - A
C3   1 4  {CCP}   ; CATHODE-PLATE	A  - C
R1   3 5  {RGI}   ; FOR GRID CURRENT	G1 - 5
D3   5 4  DX      ; FOR GRID CURRENT	5  - C
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS BTetrodeDE