**** 841-TRIODE DHT Composite ******************************************
* Created on 03/16/2013 09:54 using paint_kit.jar 
* www.bartola.co.uk/valves
* Curves image file: VT-51-841SMALL.jpg
* Data source link: VT-51-841SMALL.jpg
* Created by Ale Moglia valves@bartola.co.uk
*----------------------------------------------------------------------------------
.SUBCKT TRIODE-841-Composite 1 2 3 4 ; Plate Grid K1 K2
+ PARAMS: CCG=4P  CGP=7P CCP=3P 
+ MU=28.2 KG1=20640 KP=88 
+ KVB=6.23 VCT=-0.74 EX=1.89 RGI=2000
* Vp_MAX=500 Ip_MAX=0.016 
* Vg_step=2 Vg_start=4 Vg_count=9
* END PARAMS -----------------------------------------------------------------------
*--------------------------------------------------
  * cathode resistor is 6 ohm, the pins K1 and K2 are 1.5 ohms from the ends of it
  RFIL_LEFT    3 31 1.5
  RFIL_RIGHT   4 41 1.5
  RFIL_MIDDLE  31 41 3
  E11 32 0 VALUE={V(1,31)/KP*LOG(1+EXP(KP*(1/MU+V(2,31)/SQRT(KVB+V(1,31)*V(1,31)))))}
  E12 42 0 VALUE={V(1,41)/KP*LOG(1+EXP(KP*(1/MU+V(2,41)/SQRT(KVB+V(1,41)*V(1,41)))))}
  RE11 32 0 1G
  RE12 42 0 1G
  G11 1 31 VALUE={(PWR(V(32),EX)+PWRS(V(32),EX))/(2*KG1)}
  G12 1 41 VALUE={(PWR(V(42),EX)+PWRS(V(42),EX))/(2*KG1)}
  RCP1 1 3 1G
  RCP2 1 4 1G
  C1 2 3 {CCG} ; CATHODE-GRID
  C2 2 1 {CGP} ; GRID=PLATE
  C3 1 3 {CCP} ; CATHODE-PLATE
  D3 5 3 DX ; FOR GRID CURRENT
  D4 6 4 DX ; FOR GRID CURRENT
  RG1 2 5 {RGI} ; FOR GRID CURRENT
  RG2 2 6 {RGI} ; FOR GRID CURRENT
  .MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
  .ENDS
  *$