**** 307A TRIODE DHT Composite ******************************************
* Created on 03/16/2013 10:33 using paint_kit.jar 
* www.bartola.co.uk/valves
* Curves image file: 307a triodeSMALL.jpg
* Data source link: 307a triodeSMALL.jpg
* Created by Ale Moglia valves@bartola.co.uk
*----------------------------------------------------------------------------------
.SUBCKT TRIODE_307A-Composite 1 2 3 4 ; Plate Grid K1 K2
+ PARAMS: CCG=15P  CGP=0.5P CCP=12P 
+ MU=5.08 KG1=2610 KP=29 
+ KVB=186 VCT=-2.26 EX=1.54 RGI=2000
* Vp_MAX=200 Ip_MAX=0.08 
* Vg_step=4 Vg_start=0 Vg_count=10
* END PARAMS -----------------------------------------------------------------------
* cathode resistor is 5.5 ohm, the pins K1 and K2 are 1.375 ohms from the ends of it
RFIL_LEFT    3 31 1.375
RFIL_RIGHT   4 41 1.375
RFIL_MIDDLE  31 41 2.75
E11 32 0 VALUE={V(1,31)/KP*LOG(1+EXP(KP*(1/MU+V(2,31)/SQRT(KVB+V(1,31)*V(1,31)))))}
E12 42 0 VALUE={V(1,41)/KP*LOG(1+EXP(KP*(1/MU+V(2,41)/SQRT(KVB+V(1,41)*V(1,41)))))}
RE11 32 0 1G
RE12 42 0 1G
G11 1 31 VALUE={(PWR(V(32),EX)+PWRS(V(32),EX))/(2*KG1)}
G12 1 41 VALUE={(PWR(V(42),EX)+PWRS(V(42),EX))/(2*KG1)}
RCP1 1 3 1G
RCP2 1 4 1G
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
D4 6 4 DX ; FOR GRID CURRENT
RG1 2 5 {RGI} ; FOR GRID CURRENT
RG2 2 6 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$