801a DHT Triode Spice Model

My friend Bela, who is an experienced DHT user and very fond of the 801a, asked me if I could help in developing an LTSpice model for the venerable 801a. I have several 10/10Y but unfortunately no 801a at hand to trace so I used the data sheet curves which are a bit challenging due to resolution/scaling of the characteristic curves:

801a model from data sheet curves
801a model from data sheet curves

I had to compromise the model fit as if you want accuracy in A1 region the matching is less than perfect in A2. Still, the model is not perfect but is very good for simulation purposes.

The interesting thing was to add the grid current model for A2 operation:

A2 grid current model
A2 grid current model

Well, looking to test this model, I chose the following operating point:

801a curves test point
Test point for the model

The data sheet grid space is a bit challenging, but looking at the model in LTSpice:

Testing the 801a in LTSpice

The following slight difference can be observed:

801a test in LTSpice.

There’s about a 10% difference. Not bad considering the normal variance you’d expect in the valve anyway.

 

Here is the 801a-A2-model. Let me know your feedback:

**** 801A CURVES ** Composite DHT with Advanced Grid Current **************
* Created on 01/18/2016 19:48 using paint_kit.jar 2.9
* www.dmitrynizh.com/tubeparams_image.htm
* Plate Curves image file: 801a curves.png
* Data source link: RCA data sheet
*
* Model developed by Ale Moglia (c) 2016
* valves@bartola.co.uk
*
* www.bartola.co.uk/valves
*
*———————————————————————————-
.SUBCKT DHT-801A-A2 1 2 3 4 ; P G K1 K2
+ PARAMS: CCG=4.5P CGP=6P CCP=1.5P RFIL=6
+ MU=8 KG1=2984.1 KP=124.5 KVB=2083.2 VCT=-7.04 EX=1.29
+ VGOFF=1.17 IGA=0.00099 IGB=0.03 IGC=-18.3 IGEX=1.9
* Vp_MAX=800 Ip_MAX=250 Vg_step=10 Vg_start=100 Vg_count=20
* Rp=4000 Vg_ac=55 P_max=20 Vg_qui=-48 Vp_qui=300
* X_MIN=39 Y_MIN=33 X_SIZE=786 Y_SIZE=492 FSZ_X=1418 FSZ_Y=656 XYGrid=false
* showLoadLine=n showIp=y isDHT=y isPP=n isAsymPP=n showDissipLimit=y
* showIg1=n gridLevel2=y isInputSnapped=n
* XYProjections=n harmonicPlot=n harmonics=y
*———————————————————————————-
RFIL_LEFT 3 31 {RFIL/4}
RFIL_RIGHT 4 41 {RFIL/4}
RFIL_MIDDLE1 31 34 {RFIL/4}
RFIL_MIDDLE2 34 41 {RFIL/4}
E11 32 0 VALUE={V(1,31)/KP*LOG(1+EXP(KP*(1/MU+V(2,31)/SQRT(KVB+V(1,31)*V(1,31)))))}
E12 42 0 VALUE={V(1,41)/KP*LOG(1+EXP(KP*(1/MU+V(2,41)/SQRT(KVB+V(1,41)*V(1,41)))))}
RE11 34 0 1G
G11 1 31 VALUE={(PWR(V(32),EX)+PWRS(V(32),EX))/(2*KG1)}
G12 1 41 VALUE={(PWR(V(42),EX)+PWRS(V(42),EX))/(2*KG1)}
RCP1 1 34 1G
C1 2 34 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 34 {CCP} ; CATHODE-PLATE
RE2 2 0 1G
EGC1 81 0 VALUE={V(2,31)-VGOFF} ; POSITIVE GRID THRESHOLD
GG1 2 31 VALUE={0.5*(IGA+IGB/(IGC+V(1,31)))*(MU/KG1)*(PWR(V(81),IGEX)+PWRS(V(81),IGEX))}
EGC2 82 0 VALUE={V(2,41)-VGOFF} ; POSITIVE GRID THRESHOLD
GG2 2 41 VALUE={0.5*(IGA+IGB/(IGC+V(1,41)))*(MU/KG1)*(PWR(V(82),IGEX)+PWRS(V(82),IGEX))}
.ENDS
*$

 

Author: Ale Moglia

"A mistake is always forgivable, rarely excusable and always unacceptable. " (Robert Fripp)

3 thoughts on “801a DHT Triode Spice Model”

  1. Hi Ale, if I do remember, Thomas M. didn’t recommend using 801A in A2 region. Maybe you should ask why. BTW I have few 801A and 10Y for a line preamp. They have generally the same “sonic signature”.

    1. Hi Pierre. I’ve got experience with A2 operation in transmitting valves. Often, the bad reputation of A2 relies mainly on the challenge in the driver. A1 to A2 transition is not easy to achieve smoothly in practice. Probably is due to this. Hence is better to drive valve in pure A1 or pure A2, the latter is not possible in this valve

    2. Hi Pierre,
      As Ale wrote, the weakest part of A2 possible amp is the driver.

      I use (30mA) 10Y cathode follower (or about 15mA MOSFET source follower) to drive my PSE 801a output tubes for years ago. These tubes are “grid current hungry” beasts at A2 (I use them about up to +30-40V) region: 5-10mA grid current in 300-400V Ua region! If you drive it with strong, low impedance driver, the tone roughly remains as in A1.

      IMHO 10/10Y/VT25, 801/801a/VT62 tubes tone difference of production (I have many -few dozens- items from 6-8 manufacturers) more distinguishable, than A1/A2 difference (if you have proper driver).

Leave a Reply

Your email address will not be published. Required fields are marked *

This site uses Akismet to reduce spam. Learn how your comment data is processed.